DEFBDEFMASM;
; MASCHINENPROGRAMM ZUR ERZEUGUNG
; VON EDAS-QUELLPROGRAMMEN AUS
; DEFB BZW. DEFM -ZEILEN
; FORMAT : DATA aaaa eeee
;  aaaa - ANFANGSADRESSE
;  eeee - ENDEADRESSE
	ORG	0BA00H
VERT	EQU	0F003H
ARG4	EQU	0B788H
NAM	DEFW	0
	DEFW	0
	DEFW	0
	DEFW	0
	DEFM	'ASM'
;
DAT	DEFB	09H
	DEFM	'DEFB'
	DEFB	09H
	DEFM	'0'
DAM	DEFB	09H
	DEFM	'DEFM'
	DEFB	09H
	DEFB	27H
;
;AUSGABE UP.
OUT	PUSH	HL
	PUSH	DE
	PUSH	BC
	LD	D,0
	CALL	VERT
	DEFB	38H
	POP	BC
	POP	DE
	POP	HL
	RET
;
	DEFW	7F7FH
	DEFM	'DEFM'
	DEFB	1
	LD	A,1
	JR	XXX
;
	DEFW	7F7FH
	DEFM	'DEFB'
	DEFB	1
	LD	A,0
XXX	LD	(ARG4),A
	CALL	VERT
	DEFB	23H
	DEFM	'NAME : '
	DEFB	0
	CALL	VERT
	DEFB	17H	;INLINE
	LD	HL,7
	ADD	HL,DE	;NAMENSANFANG
	LD	DE,NAM
	LD	BC,8
	LDIR
	LD	A,00H
	LD	D,8	;INIT
	LD	HL,NAM
	CALL	VERT
	DEFB	38H
	LD	B,116
DAA0	XOR	A
	CALL	OUT
	DJNZ	DAA0	;VORBLOCK
	CALL	VERT
	DEFB	15H	;LARG
	LD	A,0AH
	CALL	OUT
	LD	A,0DH
	CALL	OUT
	LD	A,';'
	CALL	OUT
DA6	LD	A,0AH
	CALL	OUT
	LD	A,0DH
	CALL	OUT
	LD	A,M
	CP	20H
	JR	C,DA1
	CP	7FH
	JR	NC,DA1
	LD	A,(ARG4)
	AND	A
	JR	Z,DA1
	LD	C,20
	PUSH	HL
	LD	HL,DAM
	LD	B,7
DA2	LD	A,M
	CALL	OUT
	INC	HL
	DJNZ	DA2
	POP	HL
DA5	LD	A,M
	CALL	OUT
	INC	HL
	PUSH	HL
	AND	A
	SBC	HL,DE
	POP	HL
	JR	Z,DA30
	DEC	C
	JR	Z,DA4
	LD	A,M
	CP	20H
	JR	C,DA4
	CP	7FH
	JR	C,DA5
DA4	LD	A,27H
	CALL	OUT
	JR	DA6
;
DA30	LD	A,27H
	CALL	OUT
	JR	DA3
;
DA1	PUSH	HL
	LD	B,7
	LD	HL,DAT
DA7	LD	A,M
	CALL	OUT
	INC	HL
	DJNZ	DA7
	POP	HL
	LD	A,M
	AND	0F0H
	RRA
	RRA
	RRA
	RRA
	OR	30H
	CP	3AH
	JR	C,DX1
	ADD	7
DX1	CALL	OUT
	LD	A,M
	AND	0FH
	OR	30H
	CP	3AH
	JR	C,DX2
	ADD	7
DX2	CALL	OUT
	LD	A,'H'
	CALL	OUT
	INC	HL
	PUSH	HL
	AND	A
	SBC	HL,DE
	POP	HL
	JP	NZ,DA6
DA3	LD	A,3
	CALL	OUT
	LD	A,0AH
	CALL	OUT
	LD	A,0DH
	CALL	OUT
	LD	A,3
	LD	D,40H	;CLOSE
	CALL	VERT
	DEFB	38H
	RET
;***************************************
;    E N D E
ÿ