BASEXASM;---	    BASEX.KCC	    ---
;
;	Adressen 0200 0300 026A
;		(0200 02B8 026A)
;
;		` ml 05.01.1991
;------------------------------
SUTAB	EQU 0B7B0H
PV1	EQU 0F003H
AHEX	EQU 1CH
IRMON	EQU 0F018H
IRMOF	EQU 0F01BH
;-------
	ORG 00200H
RUN	DEFB 0		;1-->RUN-Switch
SUSP	DEFW 0		;Speicher SUTAB
;0203H
MBOUT	LD BC,8EF3H
	OUT (C),A	;Daten
	LD A,D
	AND 48H
	OR 37H
	BIT 3,A
	CALL NZ,NAME	;1.Block
	BIT 6,A
	JR Z,O1		;letzter Block
	LD B,A
	LD A,(RUN)
	AND A
	LD A,B
	JR Z,O1
	SET 7,A
O1	LD B,80H
	OUT (C),A
O2	IN A,(C)
	BIT 0,A
	JR NZ,O2
	BIT 7,A
	SET 0,(IX+8)	;Taste gedr}ckt
	RET Z
ERR	INC B
	IN A,(C)
	CALL PV1
	DEFB AHEX	;Fehler-Nr.
	LD HL,(0B7C9H)	;? (von BASIC)
	PUSH HL
	JP IRMOF
;023FH
MBIN	LD A,D
	AND 48H
	OR 35H
	LD C,0F3H
	BIT 3,A		;1.Block
	CALL NZ,NAME
	LD B,80H
	OUT (C),A
I1	IN A,(C)
	BIT 0,A
	JR NZ,I1
	BIT 7,A
	JR NZ,ERR
	LD B,8EH
	IN A,(C)
	RET
;025EH
NAME	LD E,11		;Anzahl
	LD B,83H
NAW	OUTI
	INC B
	INC B
	DEC E
	JR NZ,NAW
	RET
;026AH
START	LD HL,UMS
	LD DE,150H	;CALL*150
	LD BC,21H
	LDIR
	LD HL,(SUTAB)
	PUSH HL		;SUTAB alt
	LD (SUSP),HL
	LD DE,START	;SUTAB neu
	LD (SUTAB),DE
	LD BC,90H	;L{nge SUTAB
	LD HL,MBOUT
	EX (SP),HL
	PUSH HL		;SUTAB alt
	LD HL,MBIN
	EX (SP),HL
	JP 0165H
;0292H
UMS	CALL IRMON		;0150H
	LD HL,(SUSP)		;0153H
	LD DE,(SUTAB)		;0156H
	LD (SUTAB),HL		;015AH
	LD (SUSP),DE		;015DH
	CALL IRMOF		;0161H
	RET			;0164H
;-------
	LDIR			;0165H
	POP HL			;0167H
	LD (START+6EH),HL	;0168H
	POP HL			;016BH
	LD (START+70H),HL	;016CH
	RET			;016FH
;02B2H
	DEFM '141288'	;Datum
;	DEFS 300-$,0
(ÿÿÿÿÿÿÿÿÿÿÿÿÿÿÿÿÿÿÿÿ